import ../types
import ../graphics/framebuffer
import ../graphics/texture
import ../scene

const USE_SHADOW_SAMPLERS* = true

when defined(nimdoc):
    type TYPES* = ShadowManager | ShadowMapUniform

method renderShadow*(self: ShadowManager, camera: Camera): bool {.base,locks:"unknown".} =
    raise Defect.newException "Not implemented"
method destroy*(self: ShadowManager) {.base,locks:"unknown".} =
    raise Defect.newException "Not implemented"


# TODO! Call this automatically before render after one or more shadows have
# been configured.
proc updateShadowStorage*(scene: Scene) =
    ## Creates or updates the storage for all shadow maps of the scene. It must
    ## be called after `configure_shadow` and before render.
    var count = 0'i32
    var color_channels = 0
    var uses_depth = false

    for light in scene.lights:
        for s in light.shadows:
            s.shadow_index = count
            color_channels = max(color_channels, s.uses_color_channels)
            uses_depth = uses_depth or s.uses_depth
            count += s.required_texture_count
    
    if count == 0:
        return
    
    let fb_size = scene.shadow_map_resolution
    assert color_channels <= 4
    if scene.shadow_maps != nil:
        scene.shadow_maps.destroy()
    scene.shadow_maps = scene.engine.newFramebuffer(fb_size, fb_size,
            if color_channels != 0:
                (R_f16.int - 1 + color_channels).TextureFormat
            else:
                R_u8, # TODO: make fb without color attachment
            if uses_depth: DepthTexture else: DepthRenderBuffer,
            filter = Linear,
            tex_type = if color_channels != 0: Tex2DArray else: Tex2D,
            depth_tex_type = if uses_depth: Tex2DArray else: Tex2D,
            layer_count = count)
    
    scene.shadow_maps.texture.setExtrapolation Clamp
    if uses_depth:
        set_texture_shadow(scene.shadow_maps.depth_texture)
    
    # TODO: being able to use set_texture_shadow on color when needed

    # TODO: separate logic for each type of UBO?
    scene.calculate_max_lights_and_cubemaps()